Property:Query sparql

Property
name	sparql
label	sparql
type	Special:Types/Code
index	5
sortPos
primary key	False
mandatory	False
namespace
size
uploadable	False
default
inputType
allowedValues
documentation	the sparql code of the query
values from
showInGrid	False
isLink	False
allow nulls?
topic	Concept:Query

Code

This is a Property with type Special:Types/Code

Usage30

previous 20 20 50 100 250 500 next 20

Filter<p>The <a rel="nofollow" class="external text" href="https://www.semantic-mediawiki.org/wiki/Help:Property_page/Filter">search filter</a> allows the inclusion of <a rel="nofollow" class="external text" href="https://www.semantic-mediawiki.org/wiki/Help:Query_expressions">query expressions</a> such as <code>~</code> or <code>!</code>. The selected <a rel="nofollow" class="external text" href="https://www.semantic-mediawiki.org/wiki/Query_engine">query engine</a> might also support case insensitive matching or other short expressions like:</p><ul><li><code>in:</code> result should include the term, e.g. '<code>in:Foo</code>'</li></ul><ul><li><code>not:</code> result should to not include the term, e.g. '<code>not:Bar</code>'</li></ul>

Showing 10 pages using this property.

Q

Q1.7 +

SELECT DISTINCT ?programm_commitee ?programm_commiteeLabel
WHERE{
  VALUES ?series_title {"Wikidata Workshop"@en}
  VALUES ?series_type{ wd:Q47459256 wd:Q47258130 }
  ?series wdt:P31 ?series_type;
          wdt:P1476|rdfs:label ?series_title.
  ?event p:P179 [
            ps:P179 ?series;
            pq:P1545 ?ordinal
          ];
         wdt:P5804 ?programm_commitee;
         ^wdt:P4745/wdt:P179 wd:Q27230297.
  {
    SELECT (COUNT(DISTINCT ?event) as ?number_of_events)
    WHERE{
      VALUES ?series_title {"Wikidata Workshop"@en}
      VALUES ?series_type{ wd:Q47459256 wd:Q47258130 }
      ?series wdt:P31 ?series_type;
          wdt:P1476|rdfs:label ?series_title.
      ?event p:P179 [
            ps:P179 ?series;
            pq:P1545 ?ordinal
          ];
           wdt:P5804 ?programm_commitee;
           ^wdt:P4745/wdt:P179 wd:Q27230297.
      }
    }

  ?programm_commitee rdfs:label ?programm_commiteeLabel. FILTER(lang(?programm_commiteeLabel)="en")
}GROUP BY ?programm_commitee ?number_of_events ?programm_commiteeLabel
HAVING (?number_of_events = COUNT(?programm_commitee))

Q1.8 +

SELECT DISTINCT *
WHERE{
  VALUES ?conference_title {"ESWC 2022"@en}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P577 ?pub_date;
               wdt:P4745 ?workshop.
  ?workshop wdt:P11633 ?conference.  # colocated with
  ?conference wdt:P1476|rdfs:label ?conference_title.

FILTER(YEAR(?pub_date)= "2022"^^xsd:integer)
}

Q1.9 +

SELECT DISTINCT ?proceedings ?paper ?paperLabel ?event ?eventLabel ?author ?authorLabel
WHERE{
  #VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?event.

  ?paper wdt:P31 wd:Q13442814;
         wdt:P1433 ?proceedings;
         wdt:P50|wdt:P2093 ?author.
  ?event wdt:P5804 ?author.


  ?author rdfs:label ?authorLabel. FILTER(lang(?authorLabel)="en")
  ?paper rdfs:label ?paperLabel. FILTER(lang(?paperLabel)="en")
  ?event rdfs:label ?eventLabel. FILTER(lang(?eventLabel)="en")
}

Q2.1 +

PREFIX target: <http://www.wikidata.org/entity/Q115265833>

# List of authors for a work
SELECT DISTINCT
  # Author order
  ?order

  ?academic_age

  # Author item and label
  ?author ?authorUrl ?authorDescription

WHERE {
  {
    target: p:P50 ?author_statement .
    ?author_statement ps:P50 ?author_ .
    ?author_ rdfs:label ?author .
    FILTER (LANG(?author) = 'en')
    BIND(CONCAT("../author/", SUBSTR(STR(?author_), 32)) AS ?authorUrl)
    OPTIONAL {
      ?author_statement pq:P1545 ?order_ .
      BIND(xsd:integer(?order_) AS ?order)
    }
    OPTIONAL {
      ?author_ schema:description ?authorDescription .
      FILTER (LANG(?authorDescription) = "en")
    }
  }
  UNION
  {
    target: p:P2093 ?authorstring_statement .
    ?authorstring_statement ps:P2093 ?author_
    BIND(CONCAT(?author_, " ↗") AS ?author)
    OPTIONAL {
      ?authorstring_statement pq:P1545 ?order_ .
      BIND(xsd:integer(?order_) AS ?order)
    }
    BIND(CONCAT("https://author-disambiguator.toolforge.org/names_oauth.php?doit=Look+for+author&name=", ENCODE_FOR_URI(?author_)) AS ?authorUrl)
  }
  OPTIONAL {
    SELECT ?author_ (MAX(?academic_age_) AS ?academic_age) {
      target: wdt:P50 ?author_ ;
                 wdt:P577 ?publication_date .
      [] wdt:P31 / wdt:P279* wd:Q55915575 ;
         wdt:P50 ?author_ ;
         wdt:P577 ?other_publication_date .
      BIND(YEAR(?publication_date) - YEAR(?other_publication_date) AS ?academic_age_)
    }
    GROUP BY ?author_
  }
}
ORDER BY ?order

Q2.3 +

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
SELECT DISTINCT ?citingPaper ?citingPaperLabel ?paper ?paperLabel
WHERE{
  #VALUES ?proceedings {
  # wd:Q27230297
  #}
  VALUES ?paper {
    wd:Q36198963
  }
  #?paper wdt:P1433 ?proceedings.
  ?paper rdfs:label ?paperLabel.
  FILTER(lang(?paperLabel)="en")
  # cites work
  ?citingPaper wdt:P2860 ?paper.
  ?citingPaper rdfs:label ?citingPaperLabel.
  FILTER(lang(?citingPaperLabel)="en")
}

Q2.4 +

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
SELECT DISTINCT ?citingPaper ?citingPaperLabel ?paper ?paperLabel ?publicationDate
WHERE{
  #VALUES ?proceedings {
  # wd:Q27230297
  #}
  VALUES ?paper {
    wd:Q36198963
  }
  #?paper wdt:P1433 ?proceedings.
  ?paper rdfs:label ?paperLabel.
  FILTER(lang(?paperLabel)="en")
  # cites work
  ?citingPaper wdt:P2860 ?paper.
  ?citingPaper rdfs:label ?citingPaperLabel.
  FILTER(lang(?citingPaperLabel)="en")
  ?citingPaper wdt:P577 ?publicationDate
  FILTER(year(?publicationDate)>2015)
}
ORDER BY DESC(?publicationDate)

Q3.3 +

SELECT DISTINCT ?event
  (SAMPLE(?_title) as ?title)
  (SAMPLE(?_acronym) as ?acronym)
  (SAMPLE(?_startTime) as ?startTime)
  (SAMPLE(?_endTime) as ?endTime)
  (SAMPLE(?_country) as ?country)
  (SAMPLE(?_location) as ?location)
  (SAMPLE(?_officialWebsite) as ?officialWebsite)
  (SAMPLE(?_colocatedWith) as ?colocatedWith)
  (SAMPLE(?_dblpEventId) as ?dblpEventId)
  (SAMPLE(?_wikiCfpId) as ?wikiCfpId)
  (SAMPLE(?_series) as ?series)
  (SAMPLE(?_ordinal) as ?ordinal)
WHERE{
  ?proceeding wdt:P31 wd:Q1143604.
  ?proceeding wdt:P179 wd:Q27230297.
  ?proceeding p:P179/pq:P478 ?volumeNumber.
  ?proceeding wdt:P4745 ?event.
  OPTIONAL{?event wdt:P1476 ?_title. Filter(lang(?_title)="en")}
  OPTIONAL{?event wdt:P580 ?_startTime.}
  OPTIONAL{?event wdt:P582 ?_endTime.}
  OPTIONAL{?event wdt:P17 ?_country.}
  OPTIONAL{?event wdt:location ?_location.}
  OPTIONAL{?event wdt:P856 ?_officialWebsite.}
  OPTIONAL{?event wdt:P31 ?_instanceOf.}
  OPTIONAL{?event wdt:P1813 ?_acronym.}
  OPTIONAL{?event wdt:P11633 ?_colocatedWith.}
  OPTIONAL{?event wdt:P10692 ?_dblpEventId.}
  ?event wdt:P5124 ?_wikiCfpId.
  OPTIONAL{?event wdt:P179 ?_series.}
  OPTIONAL{?event p:P179/pq:P1545 ?_ordinal.}
}
GROUP BY ?event
ORDER BY DESC(?startTime)

Q3.4 +

SELECT DISTINCT ?event
  (SAMPLE(?_title) as ?title)
  (SAMPLE(?_acronym) as ?acronym)
  (SAMPLE(?_startTime) as ?startTime)
  (SAMPLE(?_endTime) as ?endTime)
  (SAMPLE(?_country) as ?country)
  (SAMPLE(?_location) as ?location)
  (SAMPLE(?_officialWebsite) as ?officialWebsite)
  (SAMPLE(?_colocatedWith) as ?colocatedWith)
  (SAMPLE(?_dblpEventId) as ?dblpEventId)
  (SAMPLE(?_wikiCfpId) as ?wikiCfpId)
  (SAMPLE(?_series) as ?series)
  (SAMPLE(?_ordinal) as ?ordinal)
WHERE{
  ?proceeding wdt:P31 wd:Q1143604.
  ?proceeding wdt:P179 wd:Q27230297.
  ?proceeding p:P179/pq:P478 ?volumeNumber.
  ?proceeding wdt:P4745 ?event.
  OPTIONAL{?event wdt:P1476 ?_title. Filter(lang(?_title)="en")}
  OPTIONAL{?event wdt:P580 ?_startTime.}
  OPTIONAL{?event wdt:P582 ?_endTime.}
  OPTIONAL{?event wdt:P17 ?_country.}
  OPTIONAL{?event wdt:location ?_location.}
  ?event wdt:P856 ?_officialWebsite.
  OPTIONAL{?event wdt:P31 ?_instanceOf.}
  OPTIONAL{?event wdt:P1813 ?_acronym.}
  OPTIONAL{?event wdt:P11633 ?_colocatedWith.}
  OPTIONAL{?event wdt:P10692 ?_dblpEventId.}
  OPTIONAL{?event wdt:P5124 ?_wikiCfpId.}
  OPTIONAL{?event wdt:P179 ?_series.}
  OPTIONAL{?event p:P179/pq:P1545 ?_ordinal.}
}
GROUP BY ?event
ORDER BY DESC(?startTime)

Q3.6 +

#defaultView:Table
PREFIX target: <http://www.wikidata.org/entity/Q27942628>

SELECT
  (MIN(?_year) as ?year)
  (MIN(?dates) AS ?date)
  ?work ?workLabel
  (GROUP_CONCAT(DISTINCT ?type_label; separator=", ") AS ?type)
  (SAMPLE(?pages_) AS ?pages)
  ?venue ?venueLabel
  (GROUP_CONCAT(DISTINCT ?author_label; separator=", ") AS ?authors)
WHERE {
  ?work wdt:P50 target: .
  ?work wdt:P50 ?author .
  OPTIONAL {
    ?author rdfs:label ?author_label_ . FILTER (LANG(?author_label_) = 'en')
  }
  BIND(COALESCE(?author_label_, SUBSTR(STR(?author), 32)) AS ?author_label)
  OPTIONAL { ?work wdt:P31 ?type_ . ?type_ rdfs:label ?type_label . FILTER (LANG(?type_label) = 'en') }
  ?work wdt:P577 ?datetimes .
  BIND(xsd:date(?datetimes) AS ?dates)
  BIND(year(?dates) as ?_year)

  OPTIONAL { ?work wdt:P1104 ?pages_ }
  OPTIONAL { ?work wdt:P1433 ?venue }
  ?work rdfs:label ?workLabel
  FILTER(LANG(?workLabel)="en")
}
GROUP BY ?work ?workLabel ?venue ?venueLabel
ORDER BY DESC(?date)

Q3.7 +

PREFIX target: <http://www.wikidata.org/entity/Q116982161>

# title: List of event and proceedings for a specific event series
SELECT DISTINCT
  (SAMPLE(?years) AS ?year)
  (SAMPLE(?ordinal) AS ?ordinal)
  (SAMPLE(?short_names) AS ?short_name)
  ?event ?eventLabel (CONCAT("/event/", SUBSTR(STR(?event), 32)) AS ?eventUrl)
  ?proceedings ?proceedingsLabel (CONCAT("/venue/", SUBSTR(STR(?proceedings), 32)) AS ?proceedingsUrl)
WHERE {
  {
    ?event wdt:P179 | wdt:P31 target: .
    ?event rdfs:label ?eventLabel.
    FILTER(LANG(?eventLabel)="en")
    OPTIONAL {
      ?event wdt:P585 | wdt:P580 ?datetime .
      BIND(YEAR(?datetime) AS ?years)
    }
    OPTIONAL {
      ?event wdt:P1813 ?short_names
    }
    OPTIONAL {
      ?proceedings wdt:P4745 ?event
    }
    OPTIONAL{
      ?event p:P179/pq:P1545 ?ordinal
    }
  }
  UNION
  {
    # proceedings even if the event is not there!!!
    ?proceedings ( wdt:P179 / wdt:P4745 ) target: .
    ?proceedings rdfs:label ?proceedingsLabel.
    FILTER(LANG(?proceedingsLabel)="en")
    OPTIONAL {
      ?proceedings wdt:P577 ?datetime .
      BIND(YEAR(?datetime) AS ?years)
    }
  }
  }
GROUP BY ?event ?year ?eventLabel ?proceedings ?proceedingsLabel
ORDER BY DESC(?year)

Property:Query sparql

Navigation menu

Search