Difference between revisions of "Semantic Publishing Challenge Queries"

From BITPlan cr Wiki
Jump to navigation Jump to search
Line 130: Line 130:
 
| Q1.7 || (chairs over the history of a workshop) Identify the full names of those chairs of the workshop series titled T that have so far been a chair in every edition of the workshop published with CEUR-WS.org
 
| Q1.7 || (chairs over the history of a workshop) Identify the full names of those chairs of the workshop series titled T that have so far been a chair in every edition of the workshop published with CEUR-WS.org
 
|-
 
|-
−
| Q1.8 || (all workshops of a conference) Identify all CEUR-WS.org proceed- ings volumes in which workshops of conference C in year Y were published |
+
| Q1.8 || (all workshops of a conference) Identify all CEUR-WS.org proceed- ings volumes in which workshops of conference C in year Y were published  
 
|-
 
|-
 
| Q1.9 || Identify those papers of workshop W that were (co-)authored by at least one chair of the workshop  
 
| Q1.9 || Identify those papers of workshop W that were (co-)authored by at least one chair of the workshop  

Revision as of 17:31, 13 March 2023


CEUR-WS Semantification Queries

Stakeholder Query Relevance

Stakeholder Interests Queries
Researcher / Author
  • finding conferences/workshops
  • finding papers
  • finding authors
  • Q1.3 & Q4.1
  • Q1.6
  • Q1.8
  • Q3.3
  • Q3.7
  • Q3.4
  • Q3.1 (show all works of an author)
Editors
  • finding authors
  • finding previous events/proceedings of the series
  • Q1.3
  • Q1.6
Organizer
  • information about the series
  • quality of submitted papers
  • Q1.20
Publisher
  • information about the editors
  • quality of proceedings/event
    • increasing/decreasing → reject/accept proceeding
  • provide access to proceedings/papers
    • increase visibility (SEO, linking to other sources)
  • Q1.1
  • Q1.8 (colocated with)
  • Q1.9
  • Q3.1
  • Q3.2
  • Q4.1
Indexer
  • metadata about
    • proceedings
    • conference(workshop
    • papers
    • editors
    • authors
  • Q1.1
  • Q1.3
  • Q1.14
  • Q4.1
  • Q4.2
Platforms (Search & Recommendation)
  • quality of papers
    • citation counts → impact of the paper
  • quality of conference/workshop
    • consistency of the event
    • quality of papers
  • subjects of paper/event
  • recomendation
    • Q1.13
    • Q3.3 (CfP)
  • trend detection
    • Q1.2
    • Q1.16
  • information retrival
    • Q1.6
    • Q1.8 (colocated with)
    • Q2.3
    • Q2.4
    • Q2.5

Queries for specific quality aspects

  • Q1.4
  • Q1.5
  • Q1.7
  • Q1.9
  • Q1.12
  • Q1.13
  • Q1.16
  • Q1.17
  • Q1.18
  • Q1.19
  • Q1.20

Queries

Q1

Query Definition
Q1.1 List the full names of all editors of the proceedings of workshop W .
Q1.2 Count the number of papers in workshop W .
Q1.3 List the full names of all authors who have (co-)authored a paper in workshop W .
Q1.4 Compute the average length of a paper (in pages) in workshop W
Q1.5 (publication turnaround) Find out whether the proceedings of work- shop W were published on CEUR-WS.org before the workshop took place.
Q1.6 (previous editions of a workshop) Identify all editions that the work- shop series titled T has published with CEUR-WS.org
Q1.7 (chairs over the history of a workshop) Identify the full names of those chairs of the workshop series titled T that have so far been a chair in every edition of the workshop published with CEUR-WS.org
Q1.8 (all workshops of a conference) Identify all CEUR-WS.org proceed- ings volumes in which workshops of conference C in year Y were published
Q1.9 Identify those papers of workshop W that were (co-)authored by at least one chair of the workshop
Q1.10 List the full names of all authors of invited papers in workshop W
Q1.11 Determine the number of editions that the workshop series titled T has had, regardless of whether published with CEUR-WS.org.
Q1.12 (change of workshop title) Determine the title (without year) that workshop W had in its first edition.
Q1.13 (workshops that have died) Of the workshops of conference C in year Y , identify those that did not publish with CEUR-WS.org in the fol- lowing year (and that therefore probably no longer took place)
Q1.14 (papers of a workshop published jointly with others) Identify the papers of the workshop titled T (which was published in a joint volume V with other workshops).
Q1.15 (editors of one workshop published jointly with others)List the full names of all editors of the proceedings of the workshop titled T (which was published in a joint volume V with other workshops)
Q1.16 Of the workshops that had editions at conference C both in year Y and Y +1, identify the workshop(s) with the biggest percentage of growth in their number of papers.
Q1.17 (change of conference affiliation) Return the acronyms of those work- shops of conference C in year Y whose previous edition was co-located with a different conference series.
Q1.18 (change of workshop date) Of the workshop series titled T , identify those editions that took place more than two months later/earlier than the previous edition published with CEUR-WS.org.
Q1.19 (institutional diversity and internationality of chairs) Identify the affiliations and countries of all editors of the proceedings of workshop W .
Q1.20 (continuity of authors) Identify the full names of those authors of papers in the workshop series titled T that have so far (co-)authored a paper in every edition of the workshop published with CEUR-WS.org

Q2

Query Definition
Q2.1 Identify the affiliations of the authors of paper X
Q2.2 Identify the papers presented at workshop X and written by researchers affiliated to an organisation located in country Y
Q2.3 Identify all works cited by paper X
Q2.4 Identify all works cited by paper X and published after year Y
Q2.5 Identify all journal papers cited by paper X
Q2.6 Identify the grant(s) that supported the research presented in paper X (or part of it)
Q2.7 Identify the funding agencies that funded the research presented in paper X (or part of it)
Q2.8 Identify the EU project(s) that supported the research presented in paper X (or part of it)
Q2.9 Identify ontologies mentioned in the abstract of paper X
Q2.10 Identify ontologies introduced in paper X (according to the abstract)

Q3

Query Definition
Q3.1 (Same entities within the CEUR-WS.org dataset) Identify and interlink same entities that appear with different URIs within the CEUR-WS.org dataset. Same persons (authors and/or editors) or same events (conferences) might have been assigned different URIs.
Q3.2 (Same entities across different datasets) Identify all different instances of the same entity in different datasets. Same entities (persons, articles, proceedings, events) might appear in different datasets with different URIs.
Q3.3 (Workshop call for papers) Link a CEUR-WS.org workshop W to its call for papers announced on EventSeer and/or WikiCfP.
Q3.4 (Workshop website) Link a workshop or conference X that appears in the CEUR-WS.org dataset to the workshop’s or conference’s website URL.
Q3.5 (Overall contribution to the conference) Identify all papers edited by an author A of a CEUR-WS.org paper P presented at workshop W co-located with conference C, and who was also author of a main track paper at the same conference C.
Q3.6 (Overall activity in a year) Identify, for an author A of a CEUR-WS.org paper P , all his/her activity in year Y .
Q3.7 (Full series of workshops) Identify the full series of workshop W regardless of whether individual editions published with CEUR-WS.org.
Q3.8 Identify people who co-authored with author A of a paper P published by CEUR-WS.org but did not co-author any CEUR-WS.org papers published in year Y with him/her.

Q4 (Addidional Queries)

Query Definition
Q4.1 Determine the complete event signature of workshop W
Q4.2 List the full names of all authors with their affiliation who have (co-)authored a paper

in workshop W (combines Q1.3 and Q2.1)


Semantic publishing Queries against wikidata

Q1.1

List the full names of all editors of the proceedings of workshop W

Input for this query is the volume number. 

SELECT ?proceedings ?editor ?editorLabel ?affiliation ?affiliationLabel
WHERE{
  VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               p:P98 [
                 ps:P98 ?editor;
                 pq:P1416 ?affiliation
               ].
  
  ?editor rdfs:label ?editorLabel. FILTER(lang(?editorLabel)="en")
  ?affiliation rdfs:label ?affiliationLabel. FILTER(lang(?affiliationLabel)="en")           
}

try it!

Q1.2

Count the number of papers in workshop W . 

SELECT ?proceedings (COUNT(DISTINCT ?paper) as ?number_of_papers)
WHERE{
  VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number.
  
  ?paper wdt:P31 wd:Q13442814;
         wdt:P1433 ?proceedings.
}
GROUP BY ?proceedings

Q1.3

List the full names of all authors who have (co-)authored a paper in workshop W . 

SELECT DISTINCT ?proceedings ?author ?authorLabel
WHERE{
  VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number.
  
  ?paper wdt:P31 wd:Q13442814;
         wdt:P1433 ?proceedings;
         wdt:P50|wdt:P2093 ?author.
  ?author rdfs:label ?authorLabel. FILTER(lang(?authorLabel)="en")
}


Q1.4

Compute the average length of a paper (in pages) in workshop W 

SELECT DISTINCT ?proceedings (AVG(?number_of_pages) as ?avg_number_of_pages)
WHERE{
  VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number.
  
  ?paper wdt:P31 wd:Q13442814;
         wdt:P1433 ?proceedings;
         wdt:P1104 ?number_of_pages.
}
GROUP BY ?proceedings

Q1.5

(publication turnaround) Find out whether the proceedings of work- shop W were published on CEUR-WS.org before the workshop took place.

This query lists all proceedings that were published before the event took place. 

SELECT DISTINCT ?proceedings ?pub_date ?event ?start_date
WHERE{
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P577 ?pub_date;
               wdt:P4745 ?event.
  ?event wdt:P580 ?start_date.
  FILTER(?pub_date < ?start_date)
}

Q1.6

(previous editions of a workshop) Identify all editions that the work- shop series titled T has published with CEUR-WS.org. 

SELECT DISTINCT ?event ?ordinal ?proceedings ?volume_number
WHERE{
  VALUES ?series_title {"Wikidata Workshop"@en}
  VALUES ?series_type{ wd:Q47459256 wd:Q47258130 }
  ?series wdt:P31 ?series_type;
          wdt:P1476|rdfs:label ?series_title.
  ?event p:P179 [
            ps:P179 ?series;
            pq:P1545 ?ordinal
          ].

  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?event.
}


Q1.7

Identify the full names of those chairs of the workshop series titled T that have so far been a chair in every edition of the workshop published with CEUR-WS.org. 

SELECT DISTINCT ?programm_commitee ?programm_commiteeLabel
WHERE{
  VALUES ?series_title {"Wikidata Workshop"@en}
  VALUES ?series_type{ wd:Q47459256 wd:Q47258130 }
  ?series wdt:P31 ?series_type;
          wdt:P1476|rdfs:label ?series_title.
  ?event p:P179 [
            ps:P179 ?series;
            pq:P1545 ?ordinal
          ];
         wdt:P5804 ?programm_commitee;
         ^wdt:P4745/wdt:P179 wd:Q27230297.
  {
    SELECT (COUNT(DISTINCT ?event) as ?number_of_events)
    WHERE{
      VALUES ?series_title {"Wikidata Workshop"@en}
      VALUES ?series_type{ wd:Q47459256 wd:Q47258130 }
      ?series wdt:P31 ?series_type;
          wdt:P1476|rdfs:label ?series_title.
      ?event p:P179 [
            ps:P179 ?series;
            pq:P1545 ?ordinal
          ];
           wdt:P5804 ?programm_commitee;
           ^wdt:P4745/wdt:P179 wd:Q27230297.
      }
    }

  ?programm_commitee rdfs:label ?programm_commiteeLabel. FILTER(lang(?programm_commiteeLabel)="en")
}GROUP BY ?programm_commitee ?number_of_events ?programm_commiteeLabel
HAVING (?number_of_events = COUNT(?programm_commitee))

Q1.8

Identify all CEUR-WS.org proceedings volumes in which workshops of conference C in year Y were published. 

SELECT DISTINCT *
WHERE{
  VALUES ?conference_title {"ESWC 2022"@en}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P577 ?pub_date;
               wdt:P4745 ?workshop.
  ?workshop wdt:P11633 ?conference.  # colocated with
  ?conference wdt:P1476|rdfs:label ?conference_title.
  
 FILTER(YEAR(?pub_date)= "2022"^^xsd:integer)
}

Q1.9

Identify those papers of workshop W that were (co-)authored by at least one chair of the workshop. 

SELECT DISTINCT ?proceedings ?paper ?paperLabel ?event ?eventLabel ?author ?authorLabel
WHERE{
  #VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?event.
  
  ?paper wdt:P31 wd:Q13442814;
         wdt:P1433 ?proceedings;
         wdt:P50|wdt:P2093 ?author.
  ?event wdt:P5804 ?author.
  
  
  ?author rdfs:label ?authorLabel. FILTER(lang(?authorLabel)="en")
  ?paper rdfs:label ?paperLabel. FILTER(lang(?paperLabel)="en")
  ?event rdfs:label ?eventLabel. FILTER(lang(?eventLabel)="en")
}

Q1.10

List the full names of all authors of invited papers in workshop W


invited papers are currently not covered by wikidata

Q1.11

Determine the number of editions that the workshop series titled T has had, regardless of whether published with CEUR-WS.org. 

SELECT DISTINCT ?series ?seriesLabel (Count(DISTINCT ?event2)as ?number_of_events)
WHERE{
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?event.
  ?event wdt:P179 ?series.
  ?event2 wdt:P179 ?series.
  ?series rdfs:label ?seriesLabel. FILTER(lang(?seriesLabel)="en")
}
GROUP BY ?series ?seriesLabel


Q1.12

(change of workshop title) Determine the title (without year) that workshop W had in its first edition. 


SELECT DISTINCT ?event ?eventLabel
WHERE{
  VALUES ?event_title {"The Third Wikidata Workshop"@en}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?e.
  ?e wdt:P179 ?series;
         wdt:P1476|rdfs:label ?event_title.
  ?event p:P179 [
                  ps:P179 ?series;
                  pq:P1545 ?ordinal
  ].
  ?event rdfs:label ?eventLabel. FILTER(lang(?eventLabel)="en")
}
ORDER BY ?ordinal
LIMIT 1


Q1.13

(workshops that have died) Of the workshops of conference C in year Y , identify those that did not publish with CEUR-WS.org in the following year (and that therefore probably no longer took place).



Q1.14

(papers of a workshop published jointly with others) Identify the papers of the workshop titled T (which was published in a joint volume V with other workshops). 


SELECT DISTINCT ?paper ?paperLabel ?proceedings
WHERE{
  VALUES ?event_title {"1st International Workshop on Knowledge Graph Generation From Text"@en}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?event.
  ?event wdt:P1476|rdfs:label ?event_title.
  ?paper wdt:P1433 ?proceedings;  # published in
         wdt:P5072 ?event. # presented in
  
  ?paper rdfs:label ?paperLabel. FILTER(lang(?paperLabel)="en")
}

Q1.15

(editors of one workshop published jointly with others) List the full names of all editors of the proceedings of the workshop titled T (which was published in a joint volume V with other workshops). 

SELECT DISTINCT ?proceedings ?event ?editor ?editorLabel
WHERE{
  VALUES ?event_title {"1st International Workshop on Knowledge Graph Generation From Text"@en}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               p:P4745 [
                            ps:P4745 ?event;
                            pq:P98 ?editor
               ].
  ?event wdt:P1476|rdfs:label ?event_title.
  
  ?editor rdfs:label ?editorLabel. FILTER(lang(?editorLabel)="en")
}
Retrieved from "https://cr.bitplan.com/index.php?title=Semantic_Publishing_Challenge_Queries&oldid=1514"