Property:Query sparql

Latest revision as of 13:15, 21 March 2023

Property
name	sparql
label	sparql
type	Special:Types/Code
index	5
sortPos
primary key	False
mandatory	False
namespace
size
uploadable	False
default
inputType
allowedValues
documentation	the sparql code of the query
values from
showInGrid	False
isLink	False
allow nulls?
topic	Concept:Query

Code

This is a Property with type Special:Types/Code

Usage30

previous 20 20 50 100 250 500 next 20

Filter<p>The <a rel="nofollow" class="external text" href="https://www.semantic-mediawiki.org/wiki/Help:Property_page/Filter">search filter</a> allows the inclusion of <a rel="nofollow" class="external text" href="https://www.semantic-mediawiki.org/wiki/Help:Query_expressions">query expressions</a> such as <code>~</code> or <code>!</code>. The selected <a rel="nofollow" class="external text" href="https://www.semantic-mediawiki.org/wiki/Query_engine">query engine</a> might also support case insensitive matching or other short expressions like:</p><ul><li><code>in:</code> result should include the term, e.g. '<code>in:Foo</code>'</li></ul><ul><li><code>not:</code> result should to not include the term, e.g. '<code>not:Bar</code>'</li></ul>

Showing 20 pages using this property.

Q

Q0.1 +

# Q0.1
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
SELECT DISTINCT ?proceeding ?volumeNumber ?title
  (SAMPLE(?_short_name) as ?short_name)
  (SAMPLE(?_pubDate) as ?pubDate)
  (SAMPLE(?_ceurwsUrl) as ?ceurwsUrl)
  (SAMPLE(?_language_of_work_or_name) as ?language_of_work_or_name)
  (SAMPLE(?_fullWorkUrl) as ?fullWorkUrl)
  (SAMPLE(?_urn) as ?urn)
  (SAMPLE(?_dblpPublicationId) as ?dblpPublicationId)
  (SAMPLE(?_K10plus) as ?K10plus)
WHERE{
  ?proceeding wdt:P31 wd:Q1143604.
  ?proceeding wdt:P179 wd:Q27230297.
  ?proceeding p:P179/pq:P478 ?volumeNumber.
  ?proceeding wdt:P1476 ?title. Filter(lang(?title)="en")
  OPTIONAL{?proceeding wdt:P1813 ?_short_name.}
  OPTIONAL{?proceeding wdt:P577 ?_pubDate.}
  OPTIONAL{?proceeding wdt:P973 ?_ceurwsUrl.}
  OPTIONAL{?proceeding wdt:P407 ?_language_of_work_or_name.}
  OPTIONAL{?proceeding wdt:953 ?_fullWorkUrl.}
  OPTIONAL{?proceeding wdt:P4109 ?_urn.}
  OPTIONAL{?proceeding wdt:P8978 ?_dblpPublicationId.}
  OPTIONAL{?proceeding wdt:P6721 ?_K10plus.}
}
GROUP BY ?volumeNumber ?proceeding ?title
ORDER BY DESC(xsd:integer(?volumeNumber))

Q0.10 +

# Query 10 of Task 0
# see https://cr.bitplan.com/index.php/Q0.10
#defaultView:Map
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX schema: <http://schema.org/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT
?event
?title
?url
?coordinates
WHERE {
  # Instance of Proceedings
  ?item wdt:P31 wd:Q1143604.
  # Part of the series
  ?item p:P179 ?partOfTheSeries.
  ?item wdt:P953 ?url.
  # CEUR Workshop proceedings
  ?partOfTheSeries ps:P179 wd:Q27230297.
  # Acronym
  OPTIONAL {?item wdt:P1813 ?short_name.}

  ?item wdt:P4745 ?event.
  ?event wdt:P1476 ?title.
  OPTIONAL{
    ?event wdt:P276 ?location.
    OPTIONAL{?location wdt:P625 ?coordinates}
    ?location rdfs:label ?locationLabel.
    FILTER(LANG(?locationLabel) = "en")
  }
}

Q0.2 +

# Q0.2 List of all papers
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
SELECT DISTINCT ?paper ?title ?proceeding ?volumeNumber
  (SAMPLE(?_url) as ?url)
  (SAMPLE(?_event) as ?event)
  (SAMPLE(?_language_of_work_or_name) as ?language_of_work_or_name)
  (GROUP_CONCAT(?_author) as ?author)
  (GROUP_CONCAT(?_authorName;SEPARATOR=",") as ?author_names)
  (SAMPLE(?_pubDate) as ?pubDate)
  (SAMPLE(?_dblpPublicationId) as ?dblpPublicationId)
WHERE{
  ?proceeding wdt:P31 wd:Q1143604.
  ?proceeding wdt:P179 wd:Q27230297.
  ?proceeding p:P179/pq:P478 ?volumeNumber.
  ?paper wdt:P1433 ?proceeding.
  ?paper wdt:P1476 ?title. Filter(lang(?title)="en")
  OPTIONAL{?paper wdt:P953  ?_url.}

  OPTIONAL{?paper wdt:P5072 ?_event.}
  OPTIONAL{
    ?paper wdt:P50 ?_author.
    ?_author rdfs:label ?_authorName.
    FILTER(LANG(?_authorName)="en")
  }

  OPTIONAL{?proceeding wdt:P407 ?_language_of_work_or_name.}
  OPTIONAL{?proceeding wdt:P8978 ?_dblpPublicationId.}
  OPTIONAL{?proceeding wdt:P577 ?_pubDate.}
} GROUP BY ?paper ?title ?proceeding ?volumeNumber
ORDER BY DESC(?pubDate)

Q0.3 +

SELECT DISTINCT ?event
  (SAMPLE(?_title) as ?title)
  (SAMPLE(?_acronym) as ?acronym)
  (SAMPLE(?_startTime) as ?startTime)
  (SAMPLE(?_endTime) as ?endTime)
  (SAMPLE(?_country) as ?country)
  (SAMPLE(?_location) as ?location)
  (SAMPLE(?_officialWebsite) as ?officialWebsite)
  (SAMPLE(?_colocatedWith) as ?colocatedWith)
  (SAMPLE(?_dblpEventId) as ?dblpEventId)
  (SAMPLE(?_wikiCfpId) as ?wikiCfpId)
  (SAMPLE(?_series) as ?series)
  (SAMPLE(?_ordinal) as ?ordinal)
WHERE{
  ?proceeding wdt:P31 wd:Q1143604.
  ?proceeding wdt:P179 wd:Q27230297.
  ?proceeding p:P179/pq:P478 ?volumeNumber.
  ?proceeding wdt:P4745 ?event.
  OPTIONAL{?event wdt:P1476 ?_title. Filter(lang(?_title)="en")}
  OPTIONAL{?event wdt:P580 ?_startTime.}
  OPTIONAL{?event wdt:P582 ?_endTime.}
  OPTIONAL{?event wdt:P17 ?_country.}
  OPTIONAL{?event wdt:P276 ?_location.}
  OPTIONAL{?event wdt:P856 ?_officialWebsite.}
  OPTIONAL{?event wdt:P31 ?_instanceOf.}
  OPTIONAL{?event wdt:P1813 ?_acronym.}
  OPTIONAL{?event wdt:P11633 ?_colocatedWith.}
  OPTIONAL{?event wdt:P10692 ?_dblpEventId.}
  OPTIONAL{?event wdt:P5124 ?_wikiCfpId.}
  OPTIONAL{?event wdt:P179 ?_series.}
  OPTIONAL{?event p:P179/pq:P1545 ?_ordinal.}
}
GROUP BY ?event
ORDER BY DESC(?startTime)

Q0.4 +

# Q0.4 List all event series
SELECT DISTINCT ?series
  (SAMPLE(?_title) as ?title)
  (SAMPLE(?_acronym) as ?acronym)
  (SAMPLE(?_officialWebsite) as ?officialWebsite)
  (GROUP_CONCAT(?_instanceOf) as ?instanceOf)
  (SAMPLE(?_dblpVenueId) as ?dblpVenueId)
  (SAMPLE(?_wikiCfpSeriesId) as ?wikiCfpSeriesId)
WHERE{
  ?proceeding wdt:P31 wd:Q1143604.
  ?proceeding wdt:P179 wd:Q27230297.
  ?proceeding p:P179/pq:P478 ?volumeNumber.
  ?proceeding wdt:P4745 ?event.
  ?event wdt:P179 ?series.
  OPTIONAL{?series wdt:P1476 ?_title. Filter(lang(?_title)="en")}
  OPTIONAL{?series wdt:P856 ?_officialWebsite.}
  OPTIONAL{?series wdt:P31 ?_instanceOf.}
  OPTIONAL{?series wdt:P1813 ?_acronym.}
  OPTIONAL{?series wdt:P8926 ?_dblpVenueId.}
  OPTIONAL{?series wdt:P5127 ?_wikiCfpSeriesId.}
}
GROUP BY ?series

Q0.5 +

# Q0.5 List all scholars (authors and editors) of CEUR-Workshop proceedings
SELECT DISTINCT
  ?scholar
  ?label
  #(GROUP_CONCAT(?_givenNameLabel) as ?givenName)
  #(GROUP_CONCAT(?_familyNameLabel) as ?familyName)
WHERE{
  # Proceeding
  ?proceeding wdt:P31 wd:Q1143604.
  # CEUR-WS
  ?proceeding wdt:P179 wd:Q27230297.
  {
    # authors
    # published in
    ?paper wdt:P1433 ?proceeding.
    # author
    ?paper wdt:P50 ?scholar.
  }UNION{
    # editors
    ?proceeding wdt:P98 ?scholar.
  }

  ?scholar rdfs:label ?label.
  FILTER(LANG(?label)="en").
  #OPTIONAL{
  #  ?scholar wdt:P735 ?_givenName.
  #  ?_givenName rdfs:label ?_givenNameLabel.
  #   FILTER(LANG(?_givenNameLabel)="en").
  #}

  #OPTIONAL{
  #  ?scholar wdt:P734 ?_familyName.
  #  ?_familyName rdfs:label ?_familyNameLabel.
  #  FILTER(LANG(?_familyNameLabel)="en").
  #}
}
GROUP BY ?scholar ?label

Q0.6 +

# Q0.6 List all institutions
SELECT DISTINCT ?institution ?institutionLabel
  (SAMPLE(?_logoImage) as ?logoImage)
  (SAMPLE(?_shortName) as ?shortName)
  (SAMPLE(?_country) as ?country)
  (SAMPLE(?_coordinateLocation) as ?coordinateLocation)
  (SAMPLE(?_officialWebsite) as ?officialWebsite)
  (SAMPLE(?_gndId) as ?gndId)
WHERE{
  ?proceeding wdt:P31 wd:Q1143604.
  ?proceeding wdt:P179 wd:Q27230297.
  {
    # authors
    ?paper wdt:P1433 ?proceeding.
    ?paper p:P50/pq:P1416 ?institution.
  }UNION{
    # editors
    ?proceeding p:P98/pq:P1416 ?institution.
  }

  OPTIONAL{?institution rdfs:label ?institutionLabel. Filter(lang(?institutionLabel)="en")}
  OPTIONAL{?institution wdt:P154 ?_logoImage.}
  OPTIONAL{?institution wdt:P1813 ?_shortName.}
  OPTIONAL{?institution wdt:P17 ?_country.}
  OPTIONAL{?institution wdt:P625 ?_coordinateLocation.}
  OPTIONAL{?institution wdt:P856 ?_officialWebsite.}
  OPTIONAL{?institution wdt:P227 ?_gndId.}
}
GROUP BY ?institution ?institutionLabel

Q0.7 +

# authors of papers of proceedings
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
SELECT DISTINCT
  ?author
  ?authorLabel
  ?paper
  ?paperLabel
  ?proceedings
  ?proceedingsLabel

WHERE{
  #VALUES ?volume_number {
  #  "3262"
  #}
  # proceedings
  ?proceedings wdt:P31 wd:Q1143604;
               # CEUR-WS
               wdt:P179 wd:Q27230297;
               # Volume
               p:P179/pq:P478 ?volume_number;
               rdfs:label ?proceedingsLabel;
               FILTER(lang(?proceedingsLabel)="en")
  # scholarly article
  ?paper wdt:P31 wd:Q13442814.

  # published in
  ?paper wdt:P1433 ?proceedings.

  ?paper rdfs:label ?paperLabel.
  FILTER(lang(?paperLabel)="en")

  # author
  ?paper wdt:P50 ?author.
  ?author rdfs:label ?authorLabel.
  FILTER(lang(?authorLabel)="en")
}

Q0.8 +

# Query 8 of Task 0
# see https://cr.bitplan.com/index.php?title=Q0.8
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX schema: <http://schema.org/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT
  ?urn
  (COUNT(?proceeding) AS ?count)
  (GROUP_CONCAT(DISTINCT CONCAT("https://ceur-ws.org/Vol-", ?sVolume, " - ", STR(?proceeding)); separator=", ") AS ?volWithProceedings)
WHERE {
   # Instance of Proceedings
   ?proceeding wdt:P31 wd:Q1143604.
   # with english label
   ?proceeding rdfs:label ?proceedingLabel.
   FILTER(LANG(?proceedingLabel) = "en")
   # Part of the series
   ?proceeding p:P179 ?partOfTheSeries.
   # Volumes via a a qualifier of the part of the series relation
   OPTIONAL { ?partOfTheSeries pq:P478 ?sVolume. }
   # CEUR Workshop proceedings
   ?partOfTheSeries ps:P179 wd:Q27230297.
   # URN-NBN
   OPTIONAL { ?proceeding wdt:P4109 ?urn. }
   #FILTER(BOUND(?urn))  # Ensure URN is available
}
GROUP BY ?urn
HAVING (COUNT(?proceeding) > 1)  # Only select URNs that appear more than once
ORDER BY DESC(?count)

Q0.9 +

# Query 9 of Task 0
# see https://cr.bitplan.com/index.php?title=Q0.9
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX schema: <http://schema.org/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?volume (COUNT(?proceeding) AS ?count) (GROUP_CONCAT(DISTINCT ?proceeding; separator=", ") AS ?proceedings)
WHERE {
   # Instance of Proceedings
   ?proceeding wdt:P31 wd:Q1143604.
   # with english label
   ?proceeding rdfs:label ?proceedingLabel.
   FILTER(LANG(?proceedingLabel) = "en")
   # Part of the series
   ?proceeding p:P179 ?partOfTheSeries.
   # CEUR Workshop proceedings
   ?partOfTheSeries ps:P179 wd:Q27230297.
   # Volumes via a qualifier of the part of the series relation
   OPTIONAL { ?partOfTheSeries pq:P478 ?sVolume. }
   # Volume via volume property
   OPTIONAL { ?proceeding wdt:P478 ?volume. }

   # Consolidate volume numbers into one variable
   BIND(COALESCE(?sVolume, ?volume) AS ?volume)
}
GROUP BY ?volume
HAVING(COUNT(?proceeding) > 1)
ORDER BY DESC(?count)

Q1.1 +

SELECT ?proceedings ?editor ?editorLabel ?affiliation ?affiliationLabel
WHERE{
  VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               p:P98 [
                 ps:P98 ?editor;
                 pq:P1416 ?affiliation
               ].

  ?editor rdfs:label ?editorLabel. FILTER(lang(?editorLabel)="en")
  ?affiliation rdfs:label ?affiliationLabel. FILTER(lang(?affiliationLabel)="en")
}

Q1.11 +

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX p: <http://www.wikidata.org/prop/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>
SELECT DISTINCT ?series ?seriesLabel (Count(DISTINCT ?event2)as ?number_of_events)
WHERE{
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?event.
  ?event wdt:P179 ?series.
  ?event2 wdt:P179 ?series.
  ?series rdfs:label ?seriesLabel. FILTER(lang(?seriesLabel)="en")
}
GROUP BY ?series ?seriesLabel
ORDER BY DESC(?number_of_events)

Q1.12 +

SELECT DISTINCT ?event ?eventLabel
WHERE{
  VALUES ?event_title {"The Third Wikidata Workshop"@en}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?e.
  ?e wdt:P179 ?series;
         wdt:P1476|rdfs:label ?event_title.
  ?event p:P179 [
                  ps:P179 ?series;
                  pq:P1545 ?ordinal
  ].
  ?event rdfs:label ?eventLabel. FILTER(lang(?eventLabel)="en")
}
ORDER BY ?ordinal
LIMIT 1

Q1.14 +

SELECT DISTINCT ?paper ?paperLabel ?proceedings
WHERE{
  VALUES ?event_title {"1st International Workshop on Knowledge Graph Generation From Text"@en}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?event.
  ?event wdt:P1476|rdfs:label ?event_title.
  ?paper wdt:P1433 ?proceedings;  # published in
         wdt:P5072 ?event. # presented in

  ?paper rdfs:label ?paperLabel. FILTER(lang(?paperLabel)="en")
}

Q1.15 +

SELECT DISTINCT ?proceedings ?event ?editor ?editorLabel
WHERE{
  VALUES ?event_title {"1st International Workshop on Knowledge Graph Generation From Text"@en}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               p:P4745 [
                            ps:P4745 ?event;
                            pq:P98 ?editor
               ].
  ?event wdt:P1476|rdfs:label ?event_title.

  ?editor rdfs:label ?editorLabel. FILTER(lang(?editorLabel)="en")
}

Q1.2 +

SELECT ?proceedings (COUNT(DISTINCT ?paper) as ?number_of_papers)
WHERE{
  VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number.

  ?paper wdt:P31 wd:Q13442814;
         wdt:P1433 ?proceedings.
}
GROUP BY ?proceedings

Q1.3 +

SELECT DISTINCT ?proceedings ?author ?authorLabel
WHERE{
  VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number.

  ?paper wdt:P31 wd:Q13442814;
         wdt:P1433 ?proceedings;
         wdt:P50|wdt:P2093 ?author.
  ?author rdfs:label ?authorLabel. FILTER(lang(?authorLabel)="en")
}

Q1.4 +

SELECT DISTINCT ?proceedings (AVG(?number_of_pages) as ?avg_number_of_pages)
WHERE{
  VALUES ?volume_number {"3262"}
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number.

  ?paper wdt:P31 wd:Q13442814;
         wdt:P1433 ?proceedings;
         wdt:P1104 ?number_of_pages.
}
GROUP BY ?proceedings

Q1.5 +

SELECT DISTINCT ?proceedings ?pub_date ?event ?start_date
WHERE{
  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P577 ?pub_date;
               wdt:P4745 ?event.
  ?event wdt:P580 ?start_date.
  FILTER(?pub_date < ?start_date)
}

Q1.6 +

SELECT DISTINCT ?event ?ordinal ?proceedings ?volume_number
WHERE{
  VALUES ?series_title {"Wikidata Workshop"@en}
  VALUES ?series_type{ wd:Q47459256 wd:Q47258130 }
  ?series wdt:P31 ?series_type;
          wdt:P1476|rdfs:label ?series_title.
  ?event p:P179 [
            ps:P179 ?series;
            pq:P1545 ?ordinal
          ].

  ?proceedings wdt:P31 wd:Q1143604;
               wdt:P179 wd:Q27230297;
               p:P179/pq:P478 ?volume_number;
               wdt:P4745 ?event.
}

@@ Line 4: / Line 4: @@
          |documentation=the sparql code of the query
 |type=Special:Types/Code
-|index=4
+|index=5
 |primaryKey=False
 |mandatory=False

Property:Query sparql

Latest revision as of 13:15, 21 March 2023

Navigation menu

Search